unit Myc.Futures;

interface

uses
    System.SysUtils,
    Myc.Signals, Myc.TaskManager;

type
    // Represents the eventual result of an asynchronous operation.
    IMycFuture<T> = interface
        {$REGION 'property access'}
        function GetResult: T;
        function GetDone: IMycState;
        {$ENDREGION}
        // Provides access to the computed result.
        property Result: T read GetResult;
        // Provides access to the completion state.
        property Done: IMycState read GetDone;
    end;

    Future<T> = record
    strict private
        FFuture: IMycFuture<T>;
        function GetDone: IMycState; inline;
        function GetResult: T; inline;

        class constructor CreateClass;
        class destructor DestroyClass;

    public
        constructor Create(const AFuture: IMycFuture<T>);
        class operator Implicit(const A: IMycFuture<T>): Future<T>; overload;
        class operator Implicit(const A: Future<T>): IMycFuture<T>; overload;

        class function Construct(const Proc: TFunc<T>): IMycFuture<T>; overload; static;
        class function Construct(const Gate: IMycState; const Proc: TFunc<T>): IMycFuture<T>; overload; static;

        function Chain<S>(const Proc: TFunc<T, S>): IMycFuture<S>;

        function WaitFor: T;

        property Done: IMycState read GetDone;
        property Result: T read GetResult;
    end;

implementation

uses
    Myc.Core.Futures, Myc.Core.Tasks;

constructor Future<T>.Create(const AFuture: IMycFuture<T>);
begin
    FFuture := AFuture;
end;

class constructor Future<T>.CreateClass;
begin
    TMycTaskFactory.AquireTaskManager;
end;

class destructor Future<T>.DestroyClass;
begin
    TMycTaskFactory.ReleaseTaskManager;
end;

function Future<T>.Chain<S>(const Proc: TFunc<T, S>): IMycFuture<S>;
begin
    var Cap := FFuture;

    Result := Future<S>.Construct( FFuture.Done,
        function: S
        begin
            Result := Proc( Cap.Result );
        end );
end;

class function Future<T>.Construct(const Proc: TFunc<T>): IMycFuture<T>;
begin
    Result := TMycInitStateFuncFuture<T>.Create( TaskManager, nil, Proc );
end;

class function Future<T>.Construct(const Gate: IMycState; const Proc: TFunc<T>): IMycFuture<T>;
begin
    Result := TMycInitStateFuncFuture<T>.Create( TaskManager, Gate, Proc );
end;

function Future<T>.GetDone: IMycState;
begin
    Result := FFuture.Done;
end;

function Future<T>.GetResult: T;
begin
    Result := FFuture.Result;
end;

function Future<T>.WaitFor: T;
begin
    TaskManager.WaitFor( FFuture.Done );
    Result := FFuture.Result;
end;

class operator Future<T>.Implicit(const A: IMycFuture<T>): Future<T>;
begin
    Result.Create( A );
end;

class operator Future<T>.Implicit(const A: Future<T>): IMycFuture<T>;
begin
    Result := A.FFuture;
end;

end.